IMAP4 Object

You can use the IMAP4 object to establish the connection with the IMAP4 server, select and manage the IMAP4 mailboxes, examine and alter properties of the messages, search for messages that match a criteria, and download entire messages.

Another features of the IMAP4 object include secure authentication options (OAuth 2.0, NTLM, GSSAPI/Kerberos and others), Integrated Windows Authentication with no username/password specified, ability to execute user-supplied commands, upload messages to the server and copy messages between mailboxes, and more.

Note: By default, the IMAP4 object neither processes Windows events nor fires its own events. This ensures maximum performance in the server environment such as ASP, but causes the user interface of desktop applications to be not responsive. To enable event handling and firing, you can set EnableEvents property value to True.

Syntax

IMAP4.property|method

Remarks

During the development, it's recommended to enable logging the IMAP4 session into a file by setting EnableLogging and LogFilePath properties. The log file allows you to discover typical problems quickly and easily.

You can find more information on typical problems resolution in Troubleshooting section of the IMAP4 samples.

Example

Dim objIMAP4, objMsg, arrNew, I

' Create IMAP4 object
Set objIMAP4 = CreateObject("MailBee.IMAP4")

' Unlock IMAP4 object
objIMAP4.LicenseKey = "put your license key here"

' Set IMAP4 server name
objIMAP4.ServerName = "mail.server.com"

' Set user credentials
objIMAP4.UserName = "username"
objIMAP4.Password = "password"

' Connect to the server and
' log in email account
If objIMAP4.Connect Then

  ' Select Inbox folder
  objIMAP4.SelectMailbox "Inbox"

  ' Get Unique-IDs of new messages
  arrNew = objIMAP4.Search(True, "new")
    
  ' Loop through new messages
  For I = LBound(arrNew) To UBound(arrNew)

    ' Completely retrieve message by its Unique-ID
    Set objMsg = objIMAP4.RetrieveSingleMessage(arrNew(I), True)

    ' Display the message
    MsgBox _
      "From: " & objMsg.FromAddr & vbCrLf & _
      "To: " & objMsg.ToAddr & vbCrLf & _
      "Subject: " & objMsg.Subject & vbCrLf & _
      "Date: " & objMsg.GetDateFromString(objMsg.Date) & vbCrLf & vbCrLf & _
      objMsg.BodyText
  Next

  ' Close the connection
  objIMAP4.Disconnect
End If

<%
Dim objIMAP4, objMsg, arrNew, I

' Create IMAP4 object
Set objIMAP4 = Server.CreateObject("MailBee.IMAP4")

' Unlock IMAP4 object
objIMAP4.LicenseKey = "put your license key here"

' Set IMAP4 server name
objIMAP4.ServerName = "mail.server.com"

' Set user credentials
objIMAP4.UserName = "username"
objIMAP4.Password = "password"

' Connect to the server and
' log in email account
If objIMAP4.Connect Then

  ' Select Inbox folder
  objIMAP4.SelectMailbox "Inbox"

  ' Get Unique-IDs of new messages
  arrNew = objIMAP4.Search(True, "new")
    
  ' Loop through new messages
  For I = LBound(arrNew) To UBound(arrNew)

    ' Completely retrieve message by its Unique-ID
    Set objMsg = objIMAP4.RetrieveSingleMessage(arrNew(I), True)

    ' Display the message.
    ' We use Server.HTMLEncode to convert '<' and '>'
    ' characters which can disturb the output if they
    ' are contained in the message headers.
    Response.Write _
      "From: " & Server.HTMLEncode(objMsg.FromAddr) & "<br>" & _
      "To: " & Server.HTMLEncode(objMsg.ToAddr) & "<br>" & _
      "Subject: " & Server.HTMLEncode(objMsg.Subject) & "<br>" & _
      "Date: " & objMsg.GetDateFromString(objMsg.Date) & "<br><br>" & _
      objMsg.BodyText
  Next

  ' Close the connection
  objIMAP4.Disconnect
End If
%>

See Also

Envelope Object, Message Object, RetrieveEnvelopes Method

Send feedback to AfterLogic
Copyright © 2002-2024, AfterLogic Corporation. All rights reserved.